Excel makro - jak vlozit formatovane cells do outlooku

Ahoj, jsem amater, pracuji na excelovskem makru, ktere vytvori v outluku email s textem podle poli, ktere jsou vlozene (proste takovy draft) (jedna se o excel a outlook2003)

funguje to dobre, pripravene hodnoty v polich pekne rozhodi a mail staci jen odeslat.
Bohuzel jedina nevyhoda je, ze to do emailu vlozi jen neformatovany text?

Nevi prosim nekdo, jak makro upravit, aby to do tela zpravy vlozilo formatovany text, popripade tabulku? (neboli rucne CTRL+C v excelu a CTRL+V v do tela zpravy )

Sub CZK_mail()

Set Outlook_Aplication = CreateObject("Outlook.Application")
Set Outlook_Aplication_MAPI = Outlook_Aplication.GetNamespace("MAPI")
Set Outlook_Aplication_ITEM = Outlook_Aplication.CreateItem(0)

Outlook_Aplication_ITEM.Importance = olImportanceHigho

Outlook_Aplication_ITEM.Display
'olMail.Display

Const olFormatHTML As Integer = 2
Const olMail As Integer = 43
Dim oOL As Object, oInsp As Object

Dim SourceTO As String
Dim SourceCC As String
Dim SourceSU As String
Dim SourceBody As String


SourceTO = Sheets("CZK").Range("A1")
SourceCC = Sheets("CZK").Range("A2")
SourceSU = Sheets("CZK").Range("A3")
SourceBody = Sheets("CZK").Range("A4")

Set oOL = CreateObject("Outlook.Application") 'uses running instance
Set oInsp = oOL.ActiveInspector

oInsp.CurrentItem.BodyFormat = olFormatHTML

Outlook_Aplication_ITEM.To = SourceTO
Outlook_Aplication_ITEM.CC = SourceCC
Outlook_Aplication_ITEM.Subject = SourceSU
Outlook_Aplication_ITEM.Body = SourceBody


'Outlook_Aplication_ITEM.Send
End Sub

tak uz nic, uz jsem to nasel.

celou dobu nic nemuzu najit, a kdyz zadam tema, tak to najdu, proste zakon schvalnosti...

Tak to sem ještě doplň ;) Jestli to není tajné. Může se to někomu hodit ;)

jj tajne to urcite neni.

Teda pastuje to do emailu selection, takze neni problem pridat vlasni vyber a selection.copy
Pro me potreby idealni.



Sub Mail_Selection_Range_Outlook_Body()




' Don't forget to copy the function RangetoHTML in the module.
' Working in Office 2000-2007
Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Dim SourceSU As String
SourceSU = Range("A12")


Set rng = Nothing
On Error Resume Next
'Only the visible cells in the selection
Set rng = Selection.SpecialCells(xlCellTypeVisible)
'You can also use a range if you want
'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(x lCellTypeVisible)
On Error GoTo 0

If rng Is Nothing Then
MsgBox "The selection is not a range or the sheet is protected" & _
vbNewLine & "please correct and try again.", vbOKOnly
Exit Sub
End If

With Application
.EnableEvents = False
.ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
OutApp.Session.Logon
Set OutMail = OutApp.CreateItem(0)

On Error Resume Next
With OutMail
.To = "nekdo@nekde.com"
.CC = ""
.BCC = ""
.Subject = SourceSU
.HTMLBody = RangetoHTML(rng)
.Display
End With
On Error GoTo 0

With Application
.EnableEvents = True
.ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing
Range("J8").Select
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2007
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook

TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With

'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With

'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.ReadAll
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function